Back to home
This game is archived.
If you with to unarchive it, click the "restore" button in the options menu.

Category:
Custom game mode

Author:
CuddlyFlower

Rating:
7

Version:
1.0.0

Posted:
9 months ago

Last updated:
9 days ago

Tags:
roadhog deathmatch growing power-ups bubbles absorption size

Project Links

Share this workshop!

Options

https://gfycat.com/metallicscholarlyearthworm-overwatch

Agar.io

Based on Agar.io. Each player starts with a bubble. The size of the bubble can be increased by absorbing players with a smaller bubble, or eating food (green) randomly spawning around the map. A player wins if the size of the bubble reaches a certain threshold (default: 30).

Features

  •    Every player starts with a small bubble. You can increase the size of the bubble by collecting food (green) or hooking other players.
  • Hooking players that are larger than you sets your size the same.
  • Besides hooking, you can also kill people by absorbing them with your bubble - as long as your bubble is larger than theirs.
  • Blue bubbles give immunity to absorption, but do not protect against hooks. It also makes it so others can walk into them.
  • You can gain a temporary blue bubble by collecting power ups (blue) and using your "Take a breather"-ability. Use it to take out larger bubbles.
  • If a bubble reaches critical size (i.e. is far ahead of all other players) it slowly loses size and also makes it so no food can be collected anymore. Furthermore, the power of food is increased for everyone.
  • You win by reaching a certain size (default: 30).

Description UI

  •    Score: your current size.
  • Fast: current speed (the larger the bubble, the slower, down to a minimum)
  • Power-ups: current size increase per food collected.
rule("SETUP (E/F: Food variables, D: Debug, W: Food size gain multiplier, M: Damage size gain Multiplier, H: Handicap)")
{
	event
	{
		Ongoing - Global;
	}

	conditions
	{
		Is Game In Progress == True;
	}

	actions
	{
		Disable Built-In Game Mode Completion;
		Disable Built-In Game Mode Scoring;
		Set Global Variable(F, Empty Array);
		Set Global Variable(E, Empty Array);
		Set Global Variable(D, False);
		Set Global Variable(W, 0.100);
		Set Global Variable(M, 0.100);
		Set Global Variable(A, 0);
		Set Global Variable(H, 5);
	}
}

rule("Setup Scores (U: Winning size, V: Players sorted after player variable R)")
{
	event
	{
		Ongoing - Global;
	}

	actions
	{
		Set Global Variable(U, 30);
		Set Global Variable(V, Sorted Array(All Players(All Teams), Subtract(0, Player Variable(Current Array Element, R))));
	}
}

rule("SETUP Speed MOdifieres (A: Speed REduction multiplier, B: Minimum speed)")
{
	event
	{
		Ongoing - Global;
	}

	conditions
	{
		Is Game In Progress == True;
	}

	actions
	{
		Set Global Variable(A, 30);
		Set Global Variable(B, 50);
	}
}

rule("SETUp Players (R: Radius - i.e. size/score, W: Can Pickup, O/P: powerups, A: Store shield entity, B: Has Inv Pickup)")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Is Game In Progress == True;
	}

	actions
	{
		Set Player Variable(Event Player, R, 1.450);
		Set Player Score(Event Player, Player Variable(Event Player, R));
		Set Player Variable(Event Player, Y, 2);
		Set Player Variable(Event Player, Z, -2.500);
		Set Player Variable(Event Player, S, 200);
		Set Move Speed(Event Player, Player Variable(Event Player, S));
		Set Player Variable(Event Player, T, Empty Array);
		Set Player Variable(Event Player, W, True);
		Set Player Variable(Event Player, O, 0);
		Set Player Variable(Event Player, P, Empty Array);
		Set Player Variable(Event Player, A, 0);
		Set Player Variable(Event Player, Q, True);
		Set Player Variable(Event Player, B, 0);
	}
}

rule("Setup coord limits (C: Center, R: Generate food)")
{
	event
	{
		Ongoing - Global;
	}

	conditions
	{
		Count Of(Players On Hero(Hero(Roadhog), All Teams)) > 0;
		Is Game In Progress == True;
	}

	actions
	{
		Set Global Variable(R, False);
		Set Global Variable(X, Sorted Array(All Players(All Teams), X Component Of(Position Of(Current Array Element))));
		Set Global Variable(Y, Sorted Array(All Players(All Teams), Y Component Of(Position Of(Current Array Element))));
		Set Global Variable(Z, Sorted Array(All Players(All Teams), Z Component Of(Position Of(Current Array Element))));
		Set Global Variable(C, Vector(Divide(Add(X Component Of(Position Of(First Of(Global Variable(X)))), X Component Of(Position Of(
			Last Of(Global Variable(X))))), 2), Divide(Add(Y Component Of(Position Of(First Of(Global Variable(Y)))), Y Component Of(
			Position Of(Last Of(Global Variable(Y))))), 2), Divide(Add(Z Component Of(Position Of(First Of(Global Variable(Z)))),
			Z Component Of(Position Of(Last Of(Global Variable(Z))))), 2)));
		Set Global Variable(X, Absolute Value(Subtract(X Component Of(Position Of(First Of(Global Variable(X)))), X Component Of(
			Position Of(Last Of(Global Variable(X)))))));
		Set Global Variable(Y, Absolute Value(Subtract(Y Component Of(Position Of(First Of(Global Variable(Y)))), Y Component Of(
			Position Of(Last Of(Global Variable(Y)))))));
		Set Global Variable(Z, Absolute Value(Subtract(Z Component Of(Position Of(First Of(Global Variable(Z)))), Z Component Of(
			Position Of(Last Of(Global Variable(Z)))))));
		Skip If(Compare(Global Variable(X), !=, 0), 1);
		Set Global Variable(X, Add(Global Variable(U), 5));
		Skip If(Compare(Global Variable(Z), !=, 0), 1);
		Set Global Variable(Z, Add(Global Variable(U), 5));
		Set Global Variable(R, True);
	}
}

rule("Setup Loss over Time")
{
	event
	{
		Ongoing - Global;
	}

	conditions
	{
		Is Game In Progress == True;
	}

	actions
	{
		Set Global Variable(L, 0.100);
	}
}

rule("Setup Powerups")
{
	event
	{
		Ongoing - Global;
	}

	conditions
	{
		Is Game In Progress == True;
	}

	actions
	{
		Set Global Variable(I, Empty Array);
		Set Global Variable(J, Empty Array);
	}
}

rule("Initital Player Spawn (Q: One-Time Flag, C: Sphere)")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Player Variable(Event Player, Q) == True;
	}

	actions
	{
		Create In-World Text(All Players(All Teams), Player Variable(Event Player, R), Event Player, 1, Clip Against Surfaces,
			Visible To Position and String, White, Default Visibility);
		Create Icon(Filtered Array(All Players(All Teams), Compare(Player Variable(Current Array Element, R), <, Player Variable(
			Event Player, R))), Event Player, Warning, Visible To and Position, Red, False);
		Set Player Variable(Event Player, Q, False);
	}
}

rule("In DISTANCE OF other PLAYERs")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Is Game In Progress == True;
		Count Of(Filtered Array(Players Within Radius(Eye Position(Event Player), Player Variable(Event Player, R), All Teams, Off), And(
			Compare(Current Array Element, !=, Event Player), Compare(Has Status(Current Array Element, Invincible), ==, False)))) >= 1;
	}

	actions
	{
		Set Player Variable(Event Player, T, First Of(Filtered Array(Players Within Radius(Eye Position(Event Player), Player Variable(
			Event Player, R), All Teams, Off), And(Compare(Event Player, !=, Current Array Element), Compare(Has Status(Event Player,
			Invincible), ==, False)))));
		Abort If(Compare(Player Variable(Player Variable(Event Player, T), R), >=, Player Variable(Event Player, R)));
		Set Player Variable(Event Player, R, Add(Global Variable(M), Player Variable(Event Player, R)));
		Kill(Player Variable(Event Player, T), Event Player);
		Set Move Speed(Event Player, Max(Global Variable(B), Subtract(Player Variable(Event Player, S), Multiply(Global Variable(A),
			Player Variable(Event Player, R)))));
		Set Player Variable(Event Player, Y, Add(Player Variable(Event Player, Y), 0.200));
		Set Player Variable(Event Player, Z, Subtract(Player Variable(Event Player, Z), 0.200));
		Wait(0.200, Ignore Condition);
		Loop If Condition Is True;
	}
}

rule("In Distance of food")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Is Alive(Event Player) == True;
		Is Game In Progress == True;
		Player Variable(Event Player, W) == True;
		Count Of(Filtered Array(Global Variable(F), Compare(Distance Between(Eye Position(Event Player), Current Array Element), <=,
			Player Variable(Event Player, R)))) >= 1;
	}

	actions
	{
		Set Player Variable(Event Player, W, False);
		Set Player Variable(Event Player, I, Index Of Array Value(Global Variable(F), First Of(Filtered Array(Global Variable(F), Compare(
			Distance Between(Eye Position(Event Player), Current Array Element), <=, Player Variable(Event Player, R))))));
		Set Player Variable(Event Player, J, Empty Array);
		Set Player Variable(Event Player, J, Append To Array(Player Variable(Event Player, J), Value In Array(Global Variable(E), Multiply(
			Player Variable(Event Player, I), 2))));
		Set Player Variable(Event Player, J, Append To Array(Player Variable(Event Player, J), Value In Array(Global Variable(E), Add(
			Multiply(Player Variable(Event Player, I), 2), 1))));
		Set Global Variable(F, Filtered Array(Global Variable(F), Compare(Index Of Array Value(Global Variable(F), Current Array Element),
			!=, Player Variable(Event Player, I))));
		Set Global Variable(E, Filtered Array(Global Variable(E), Compare(Array Contains(Player Variable(Event Player, J),
			Current Array Element), ==, False)));
		Destroy Effect(Value In Array(Player Variable(Event Player, J), 0));
		Destroy Effect(Value In Array(Player Variable(Event Player, J), 1));
		Skip If(Compare(Subtract(Player Variable(Event Player, R), Global Variable(H)), >=, Player Variable(Value In Array(Global Variable(
			V), 1), R)), 2);
		Set Player Variable(Event Player, R, Add(Player Variable(Event Player, R), Global Variable(W)));
		Set Move Speed(Event Player, Max(Global Variable(B), Subtract(Player Variable(Event Player, S), Multiply(Global Variable(A),
			Player Variable(Event Player, R)))));
		Play Effect(All Players(All Teams), Buff Explosion Sound, White, Event Player, 200);
		Play Effect(All Players(All Teams), Good Explosion, Green, Event Player, 5);
		Skip If(Compare(Subtract(Player Variable(Event Player, R), Global Variable(H)), <, Player Variable(Value In Array(Global Variable(
			V), 1), R)), 1);
		Big Message(Event Player, String("Critical", Null, Null, Null));
		Wait(0.100, Ignore Condition);
		Set Player Variable(Event Player, W, True);
		Loop If Condition Is True;
	}
}

rule("In Distance of Invincibility Power up")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Is Alive(Event Player) == True;
		Is Game In Progress == True;
		Player Variable(Event Player, W) == True;
		Count Of(Filtered Array(Global Variable(I), Compare(Distance Between(Position Of(Event Player), Current Array Element), <=, 2)))
			>= 1;
	}

	actions
	{
		Set Player Variable(Event Player, W, False);
		Set Player Variable(Event Player, O, Index Of Array Value(Global Variable(I), First Of(Filtered Array(Global Variable(I), Compare(
			Distance Between(Position Of(Event Player), Current Array Element), <, 2)))));
		Set Player Variable(Event Player, P, Array Slice(Global Variable(J), Multiply(Player Variable(Event Player, O), 2), 2));
		Set Global Variable(J, Filtered Array(Global Variable(J), Compare(Array Contains(Player Variable(Event Player, P),
			Current Array Element), ==, False)));
		Set Global Variable(I, Filtered Array(Global Variable(I), Compare(Index Of Array Value(Global Variable(I), Current Array Element),
			!=, Player Variable(Event Player, O))));
		Destroy Effect(Value In Array(Player Variable(Event Player, P), 0));
		Destroy Effect(Value In Array(Player Variable(Event Player, P), 1));
		Play Effect(All Players(All Teams), Explosion Sound, White, Event Player, 1000);
		Big Message(Event Player, String("{0} {1}", String("Ability 2", Null, Null, Null), String("Obtained", Null, Null, Null), Null));
		Set Player Variable(Event Player, B, True);
		Set Ability 2 Enabled(Event Player, True);
		Set Player Variable(Event Player, W, True);
		Wait(1, Ignore Condition);
		Loop If Condition Is True;
	}
}

rule("GEnerate Food")
{
	event
	{
		Ongoing - Global;
	}

	conditions
	{
		Is Game In Progress == True;
		Global Variable(R) == True;
		Count Of(Global Variable(F)) < 10;
	}

	actions
	{
		Set Global Variable(R, False);
		Set Global Variable(K, Nearest Walkable Position(Add(Global Variable(C), Vector(Random Real(Subtract(0, Global Variable(X)),
			Global Variable(X)), Random Real(Subtract(0, Global Variable(Y)), Global Variable(Y)), Random Real(Subtract(0, Global Variable(
			Z)), Global Variable(Z))))));
		Wait(0.050, Ignore Condition);
		Loop If(Compare(Count Of(Filtered Array(All Living Players(All Teams), Compare(Distance Between(Current Array Element,
			Global Variable(K)), <=, Player Variable(Current Array Element, R)))), >=, 1));
		Wait(0.050, Ignore Condition);
		Loop If(Compare(Count Of(Filtered Array(Global Variable(F), Compare(Distance Between(Current Array Element, Global Variable(K)),
			<=, 2))), >=, 1));
		Set Global Variable(K, Add(Global Variable(K), Vector(0, 0.250, 0)));
		Create Effect(All Players(All Teams), Light Shaft, Green, Global Variable(K), 1, None);
		Set Global Variable(E, Append To Array(Global Variable(E), Last Created Entity));
		Create Effect(All Players(All Teams), Good Aura, Green, Add(Global Variable(K), Vector(0, 0.500, 0)), 1, None);
		Set Global Variable(E, Append To Array(Global Variable(E), Last Created Entity));
		Set Global Variable(F, Append To Array(Global Variable(F), Global Variable(K)));
		Wait(0.500, Ignore Condition);
		Set Global Variable(R, True);
		Loop If Condition Is True;
	}
}

rule("Generate Invincibility Powerup")
{
	event
	{
		Ongoing - Global;
	}

	conditions
	{
		Is Game In Progress == True;
		Global Variable(R) == True;
		Count Of(Global Variable(I)) < 3;
	}

	actions
	{
		Wait(13, Ignore Condition);
		Set Global Variable(N, Position Of(Random Value In Array(Array Slice(Global Variable(V), Round To Integer(Divide(Count Of(
			Global Variable(V)), 2), Down), Round To Integer(Divide(Count Of(Global Variable(V)), 2), Up)))));
		Set Global Variable(N, Nearest Walkable Position(Global Variable(N)));
		Wait(3, Ignore Condition);
		Set Global Variable(I, Append To Array(Global Variable(I), Global Variable(N)));
		Create Effect(All Players(All Teams), Orb, Blue, Add(Global Variable(N), Vector(0, 0.500, 0)), 1, None);
		Set Global Variable(J, Append To Array(Global Variable(J), Last Created Entity));
		Create Effect(All Players(All Teams), Light Shaft, Blue, Global Variable(N), 1, None);
		Set Global Variable(J, Append To Array(Global Variable(J), Last Created Entity));
		Wait(1, Ignore Condition);
		Loop If Condition Is True;
	}
}

rule("Reset Player score on death")
{
	event
	{
		Player Died;
		All;
		All;
	}

	actions
	{
		Destroy Effect(Player Variable(Event Player, Z));
		Set Player Variable(Event Player, R, 1.450);
		Set Player Score(Event Player, Player Variable(Event Player, R));
		Set Move Speed(Event Player, Player Variable(Event Player, S));
		Set Player Variable(Event Player, U, 0);
	}
}

rule("Respawned")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Has Spawned(Event Player) == True;
	}

	actions
	{
		Set Ability 2 Enabled(Event Player, Player Variable(Event Player, B));
		Set Status(Event Player, Null, Invincible, 9999);
		Wait(2, Ignore Condition);
		Big Message(Event Player, String("Good Luck", Null, Null, Null));
		Wait(1, Ignore Condition);
		Clear Status(Event Player, Invincible);
	}
}

rule("Change To First Person")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Is Button Held(Event Player, Primary Fire) == False;
	}

	actions
	{
		Stop Camera(Event Player);
	}
}

rule("Change to Overhead View")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Is Button Held(Event Player, Primary Fire) == True;
	}

	actions
	{
		Start Camera(Event Player, World Vector Of(Vector(0, Add(Multiply(Player Variable(Event Player, R), 2), 10), -0.050), Event Player,
			Rotation And Translation), World Vector Of(Vector(0, 0, 0), Event Player, Rotation And Translation), 0);
	}
}

rule("Hook damage transfers Size")
{
	event
	{
		Player Took Damage;
		All;
		All;
	}

	actions
	{
		Clear Status(Event Player, Invincible);
		Skip If(Compare(Player Variable(Attacker, R), >=, Player Variable(Event Player, R)), 1);
		Set Player Variable(Attacker, R, Player Variable(Event Player, R));
		Set Move Speed(Event Player, Max(Global Variable(B), Subtract(Player Variable(Event Player, S), Multiply(Global Variable(A),
			Player Variable(Event Player, R)))));
		Set Move Speed(Attacker, Max(Global Variable(B), Subtract(Player Variable(Attacker, S), Multiply(Global Variable(A),
			Player Variable(Attacker, R)))));
		Set Player Variable(Attacker, R, Add(Global Variable(M), Player Variable(Attacker, R)));
		Kill(Event Player, Attacker);
	}
}

rule("Clear invincibility on hook")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Has Status(Event Player, Stunned) == True;
	}

	actions
	{
		Clear Status(Event Player, Invincible);
		Kill(Event Player, Null);
	}
}

rule("Player Using Ability 2 (Powerup)")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Is Using Ability 2(Event Player) == True;
	}

	actions
	{
		Wait(1.500, Ignore Condition);
		Big Message(Event Player, String("{0}!", String("Protected", Null, Null, Null), Null, Null));
		Set Player Variable(Event Player, B, False);
		Set Ability 2 Enabled(Event Player, False);
		Set Status(Event Player, Null, Invincible, 9999);
		Wait(6, Ignore Condition);
		Big Message(Event Player, String("{0} {1}", String("Sphere", Null, Null, Null), String("Failing", Null, Null, Null), Null));
		Wait(2, Ignore Condition);
		Clear Status(Event Player, Invincible);
	}
}

rule("Invincibility ON")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Has Status(Event Player, Invincible) == True;
	}

	actions
	{
		Destroy Effect(Player Variable(Event Player, C));
		Wait(0.250, Ignore Condition);
		Destroy Effect(Player Variable(Event Player, C));
		Create Effect(All Players(All Teams), Sphere, Blue, Eye Position(Event Player), Player Variable(Event Player, R),
			Visible To Position and Radius);
		Set Player Variable(Event Player, C, Last Created Entity);
	}
}

rule("Invincibility off")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Has Status(Event Player, Invincible) == False;
	}

	actions
	{
		Destroy Effect(Player Variable(Event Player, C));
		Wait(0.250, Ignore Condition);
		Destroy Effect(Player Variable(Event Player, C));
		Create Effect(All Players(All Teams), Sphere, White, Eye Position(Event Player), Player Variable(Event Player, R),
			Visible To Position and Radius);
		Set Player Variable(Event Player, C, Last Created Entity);
	}
}

rule("UI - All")
{
	event
	{
		Ongoing - Global;
	}

	actions
	{
		Create HUD Text(All Players(All Teams), Null, 1.010, Null, Right, 0, White, White, White, Visible To and String,
			Default Visibility);
	}
}

rule("UI - Player")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Is Game In Progress == True;
	}

	actions
	{
		Create HUD Text(Event Player, Null, String("Power-ups", Null, Null, Null), Global Variable(W), Left, 0, White, White, White,
			Visible To and String, Default Visibility);
		Create HUD Text(Event Player, Null, String("Fast", Null, Null, Null), Divide(Player Variable(Event Player, U), Player Variable(
			Event Player, S)), Left, 0, White, White, White, Visible To and String, Default Visibility);
		Create HUD Text(Event Player, Null, String("{0} {1}", String("Score", Null, Null, Null), String("Goal", Null, Null, Null), Null),
			Global Variable(U), Left, 0, White, Green, White, Visible To and String, Default Visibility);
		Create HUD Text(Event Player, Null, String("{0} {1}", String("Current", Null, Null, Null), String("Score", Null, Null, Null),
			Null), Player Variable(Event Player, R), Left, 0, White, Red, White, Visible To and String, Default Visibility);
	}
}

rule("Calculate Current Speed")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Is Game In Progress == True;
	}

	actions
	{
		Set Player Variable(Event Player, U, Max(Global Variable(B), Subtract(Player Variable(Event Player, S), Multiply(Subtract(
			Player Variable(Event Player, R), 1), Global Variable(A)))));
		Wait(0.250, Ignore Condition);
		Loop If Condition Is True;
	}
}

rule("Scores")
{
	event
	{
		Ongoing - Global;
	}

	conditions
	{
		Is Game In Progress == True;
	}

	actions
	{
		Set Global Variable(V, Sorted Array(All Players(All Teams), Subtract(0, Player Variable(Current Array Element, R))));
		Skip If(Or(Compare(Count Of(Global Variable(V)), <=, 1), Compare(Player Variable(First Of(Global Variable(V)), R), <,
			Global Variable(U))), 1);
		Declare Player Victory(First Of(Global Variable(V)));
		Wait(0.250, Ignore Condition);
		Loop If Condition Is True;
	}
}

rule("Update Scores of players")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		Is Game In Progress == True;
	}

	actions
	{
		Set Player Score(Event Player, Player Variable(Event Player, R));
		Wait(0.250, Ignore Condition);
		Loop If Condition Is True;
	}
}

rule("update leading player")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		First Of(Global Variable(V)) == Event Player;
		Count Of(Global Variable(V)) > 1;
		Compare(Subtract(Player Variable(Event Player, R), Global Variable(H)), >, Player Variable(Value In Array(Global Variable(V), 1),
			R)) == True;
	}

	actions
	{
		Set Player Variable(Event Player, R, Subtract(Player Variable(Event Player, R), Global Variable(L)));
		Small Message(Event Player, String("Critical", Null, Null, Null));
		Wait(1, Ignore Condition);
		Loop If Condition Is True;
	}
}

rule("Increase Food value depending on first player")
{
	event
	{
		Ongoing - Global;
	}

	conditions
	{
		Is Game In Progress == True;
		Count Of(Global Variable(V)) > 1;
		Compare(Subtract(Player Variable(First Of(Global Variable(V)), R), Global Variable(H)), >, Player Variable(Value In Array(
			Global Variable(L), 1), R)) == True;
	}

	actions
	{
		Set Global Variable(W, Add(Global Variable(W), 0.200));
		Wait(15, Ignore Condition);
		Loop If Condition Is True;
	}
}

rule("Debug")
{
	event
	{
		Ongoing - Each Player;
		All;
		Slot 0;
	}

	conditions
	{
		Global Variable(D) == True;
	}

	actions
	{
		Set Player Variable(Event Player, D, World Vector Of(Vector(0, 0, 0), Event Player, Rotation And Translation));
		Wait(0.100, Ignore Condition);
		Skip If(Compare(Count Of(Global Variable(F)), ==, Count Of(Global Variable(E))), 1);
		Big Message(Event Player, String("{0} != {1}", Count Of(Global Variable(E)), Count Of(Global Variable(F)), Null));
		Loop If Condition Is True;
	}
}

Changelog

9 months ago 1.0.0

This revision contains no notes

5WCWC
click to copy
9 months ago 1.0.0

This revision contains no notes

1RJVP
click to copy